Fix #45: Add --with-udev[=PATH] to configure, disables classic SUID root

This patch adds support for installing the 90-backlight.rules to gain
privileges to the kernel sysfs files.  By default the classic SUID root
mode is used and the rules file is not installed.

Signed-off-by: Joachim Nilsson <troglobit@gmail.com>

Makefile.am

@@ -3,6 +3,11 @@ dist_man1_MANS = light.1
 doc_DATA       = README.md LICENSE CHANGELOG
 EXTRA_DIST     = README.md LICENSE CHANGELOG
 
+if UDEV
+udev_DATA      = 90-backlight.rules
+EXTRA_DIST    += $(top_srcdir)/90-backlight.rules
+endif
+
 #
 # Target to run when building a release
 #

README.md

@@ -175,13 +175,16 @@ because they are generated at release time with `make release`.
 
 ### Permissions
 
-**Optional:** Instead of SUID root you can set up udev rules to manage
-   sysfs permissions, you may skip the `make install` step and instead
-   copy the file `90-backlight.rules` to `/etc/udev/rules.d/`:
+Optionally, instead of the classic SUID root mode of operation, udev
+rules can be set up to manage the kernel sysfs permissions.  Use the
+configure script to enable this mode of operation:
 
+    ./configure --with-udev && make
+    sudo make install
+
+This installs the file `90-backlight.rules` into `/lib/udev/rules.d/`.
+If your udev rules are located elsewhere, use `--with-udev=PATH`.
 
-    ACTION=="add", SUBSYSTEM=="backlight", RUN+="/bin/chgrp video /sys/class/backlight/%k/brightness"
-    ACTION=="add", SUBSYSTEM=="backlight", RUN+="/bin/chmod g+w /sys/class/backlight/%k/brightness"
 
 
 Origin & References

configure.ac

@@ -10,4 +10,25 @@ AC_PROG_CC
 AC_PROG_INSTALL
 AC_HEADER_STDC
 
+AC_ARG_WITH([udev],
+	AS_HELP_STRING([--with-udev@<:@=PATH@:>@], [use udev instead of SUID root, optional rules.d path]),
+	[udev=$withval], [udev=no])
+
+AC_MSG_CHECKING(for udev rules.d)
+AS_IF([test "x$udev" != "xno"], [
+	AS_IF([test "x$udev" = "xyes"], [
+		udevdir="\${prefix}/lib/udev/rules.d"
+	],[
+		udevdir="$udev"
+	])
+	AC_SUBST(udevdir)
+	AC_MSG_RESULT([$udevdir])
+],[
+	AC_MSG_RESULT([disabled, classic SUID root mode])
+])
+
+# Allow classic SUID root behavior if udev rule is not used
+AM_CONDITIONAL(UDEV,    [test "x$udev" != "xno"])
+AM_CONDITIONAL(CLASSIC, [test "x$udev"  = "xno"])
+
 AC_OUTPUT

src/Makefile.am

@@ -3,5 +3,7 @@ light_SOURCES  = main.c light.c light.h helpers.c helpers.h
 light_CPPFLAGS = -I../include -D_XOPEN_SOURCE=500
 light_CFLAGS   = -W -Wall -Wextra -std=gnu99 -Wno-type-limits
 
+if CLASSIC
 install-exec-hook:
 	chmod 4755 $(DESTDIR)$(bindir)/light
+endif