Added flake8 checker to vim (press F7)

[Flake8](http://pypi.python.org/pypi/flake8/) is a wrapper around
PyFlakes (static syntax checker), PEP8 (style checker) and Ned's
MacCabe script (complexity checker).

dotfiles/vim/bundle/vim-flake8/README.mdown

@@ -0,0 +1,88 @@
+vim-flake8
+==========
+`vim-flake8` is a Vim plugin that runs the currently open file through Flake8,
+a static syntax and style checker for Python source code.  It supersedes both
+[vim-pyflakes](https://github.com/nvie/vim-pyflakes) and
+[vim-pep8](https://github.com/nvie/vim-pep8).
+
+[Flake8](http://pypi.python.org/pypi/flake8/) is a wrapper around PyFlakes 
+(static syntax checker), PEP8 (style checker) 
+and Ned's MacCabe script (complexity checker).
+
+
+Installation
+------------
+Use [vim-pathogen](https://github.com/tpope/vim-pathogen) if you're not using
+it already.  Make sure you've installed the [flake8](http://pypi.python.org/pypi/flake8/) package.
+Then, simply put the contents of this repository in your
+`~/.vim/bundle` directory.
+
+Usage
+-----
+1. Open a Python file
+2. Press `<F7>` to run `flake8` on it
+
+It shows the errors inside a quickfix window, which will allow your to quickly
+jump to the error locations by simply pressing [Enter].
+
+
+Customization
+-------------
+If you don't want to use the `<F7>` key for flake8-checking, simply remap it to
+another key.  It autodetects whether it has been remapped and won't register
+the `<F7>` key if so.  For example, to remap it to `<F3>` instead, use:
+
+    autocmd FileType python map <buffer> <F3> :call Flake8()<CR>
+
+To add builtins, in your .vimrc:
+
+    let g:flake8_builtins="_,apply"
+
+To ignore errors, in your .vimrc:
+
+    let g:flake8_ignore="E501,W293"
+
+If you want to change the max line length for PEP8:
+
+    let g:flake8_max_line_length=99
+
+To set the maximum [McCabe complexity](https://en.wikipedia.org/wiki/Cyclomatic_complexity) before a warning is issued:
+
+    let g:flake8_max_complexity=10
+
+To customize the location of your flake8 binary, set `g:flake8_cmd`:
+
+    let g:flake8_cmd="/opt/strangebin/flake8000"
+
+
+Tips
+----
+A tip might be to run the Flake8 check every time you write a Python file, to
+enable this, add the following line to your `.vimrc` file (thanks
+[Godefroid](http://github.com/gotcha)!):
+
+    autocmd BufWritePost *.py call Flake8()
+
+This plugin goes well together with the following plugin:
+
+- [PyUnit](http://github.com/nvie/vim-pyunit) (unit test helper under `<F8>`
+  and `<F9>`)
+
+
+History
+-------
+
+1.3: Added the following options:
+
+     - `g:flake8_builtins="_,apply"`
+     - `g:flake8_max_complexity=10`
+
+1.2: Added the following options:
+
+     - `g:flake8_cmd="/opt/strangebin/flake8000"`
+     - `g:flake8_max_line_length=120`
+     - `g:flake8_ignore="E501,W293"`
+
+1.1: Added `g:flake8_ignore` option.
+
+1.0: Initial version.

dotfiles/vim/bundle/vim-flake8/ftplugin/python_flake8.vim

@@ -0,0 +1,102 @@
+"
+" Python filetype plugin for running flake8
+" Language:     Python (ft=python)
+" Maintainer:   Vincent Driessen <vincent@3rdcloud.com>
+" Version:      Vim 7 (may work with lower Vim versions, but not tested)
+" URL:          http://github.com/nvie/vim-flake8
+"
+" Only do this when not done yet for this buffer
+if exists("b:loaded_flake8_ftplugin")
+    finish
+endif
+let b:loaded_flake8_ftplugin=1
+
+if !exists("*Flake8()")
+    function Flake8()
+        if exists("g:flake8_cmd")
+            let s:flake8_cmd=g:flake8_cmd
+        else
+            let s:flake8_cmd="flake8"
+        endif
+
+        if !executable(s:flake8_cmd)
+            echoerr "File " . s:flake8_cmd . " not found. Please install it first."
+            return
+        endif
+
+        set lazyredraw   " delay redrawing
+        cclose           " close any existing cwindows
+
+        " store old grep settings (to restore later)
+        let l:old_gfm=&grepformat
+        let l:old_gp=&grepprg
+
+        " write any changes before continuing
+        if &readonly == 0
+            update
+        endif
+
+        " read config
+        if exists("g:flake8_builtins")
+            let s:flake8_builtins_opt=" --builtins=".g:flake8_builtins
+        else
+            let s:flake8_builtins_opt=""
+        endif
+
+        if exists("g:flake8_ignore")
+            let s:flake8_ignores=" --ignore=".g:flake8_ignore
+        else
+            let s:flake8_ignores=""
+        endif
+
+        if exists("g:flake8_max_line_length")
+            let s:flake8_max_line_length=" --max-line-length=".g:flake8_max_line_length
+        else
+            let s:flake8_max_line_length=""
+        endif
+
+        if exists("g:flake8_max_complexity")
+            let s:flake8_max_complexity=" --max-complexity=".g:flake8_max_complexity
+        else
+            let s:flake8_max_complexity=""
+        endif
+
+        " perform the grep itself
+        let &grepformat="%f:%l:%c: %m\,%f:%l: %m"
+        let &grepprg=s:flake8_cmd.s:flake8_builtins_opt.s:flake8_ignores.s:flake8_max_line_length.s:flake8_max_complexity
+        silent! grep! %
+
+        " restore grep settings
+        let &grepformat=l:old_gfm
+        let &grepprg=l:old_gp
+
+        " open cwindow
+        let has_results=getqflist() != []
+        if has_results
+            execute 'belowright copen'
+            setlocal wrap
+            nnoremap <buffer> <silent> c :cclose<CR>
+            nnoremap <buffer> <silent> q :cclose<CR>
+        endif
+
+        set nolazyredraw
+        redraw!
+
+        if has_results == 0
+            " Show OK status
+            hi Green ctermfg=green
+            echohl Green
+            echon "Flake8 check OK"
+            echohl
+        endif
+    endfunction
+endif
+
+" Add mappings, unless the user didn't want this.
+" The default mapping is registered under to <F7> by default, unless the user
+" remapped it already (or a mapping exists already for <F7>)
+if !exists("no_plugin_maps") && !exists("no_flake8_maps")
+    if !hasmapto('Flake8(')
+        noremap <buffer> <F7> :call Flake8()<CR>
+    endif
+endif