python.vim 32KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639
  1. " Vim syntax file
  2. " Language: Python
  3. " Current Maintainer: Dmitry Vasiliev <dima at hlabs dot org>
  4. " Previous Maintainer: Neil Schemenauer <nas at python dot ca>
  5. " URL: https://github.com/hdima/python-syntax
  6. " Last Change: 2015-11-01
  7. " Filenames: *.py
  8. " Version: 3.6.0
  9. "
  10. " Based on python.vim (from Vim 6.1 distribution)
  11. " by Neil Schemenauer <nas at python dot ca>
  12. "
  13. " Please use the following channels for reporting bugs, offering suggestions or
  14. " feedback:
  15. " - python.vim issue tracker: https://github.com/hdima/python-syntax/issues
  16. " - Email: Dmitry Vasiliev (dima at hlabs.org)
  17. " - Send a message or follow me for updates on Twitter: `@hdima
  18. " <https://twitter.com/hdima>`__
  19. "
  20. " Contributors
  21. " ============
  22. "
  23. " List of the contributors in alphabetical order:
  24. "
  25. " Andrea Riciputi
  26. " Anton Butanaev
  27. " Antony Lee
  28. " Caleb Adamantine
  29. " David Briscoe
  30. " Elizabeth Myers
  31. " Ihor Gorobets
  32. " Jeroen Ruigrok van der Werven
  33. " John Eikenberry
  34. " Joongi Kim
  35. " Marc Weber
  36. " Pedro Algarvio
  37. " Victor Salgado
  38. " Will Gray
  39. " Yuri Habrusiev
  40. "
  41. " Options
  42. " =======
  43. "
  44. " :let OPTION_NAME = 1 Enable option
  45. " :let OPTION_NAME = 0 Disable option
  46. "
  47. "
  48. " Option to select Python version
  49. " -------------------------------
  50. "
  51. " python_version_2 Enable highlighting for Python 2
  52. " (Python 3 highlighting is enabled
  53. " by default). Can also be set as
  54. " a buffer (b:python_version_2)
  55. " variable.
  56. "
  57. " You can also use the following local to buffer commands to switch
  58. " between two highlighting modes:
  59. "
  60. " :Python2Syntax Switch to Python 2 highlighting
  61. " mode
  62. " :Python3Syntax Switch to Python 3 highlighting
  63. " mode
  64. "
  65. " Option names used by the script
  66. " -------------------------------
  67. "
  68. " python_highlight_builtins Highlight builtin functions and
  69. " objects
  70. " python_highlight_builtin_objs Highlight builtin objects only
  71. " python_highlight_builtin_funcs Highlight builtin functions only
  72. " python_highlight_exceptions Highlight standard exceptions
  73. " python_highlight_string_formatting Highlight % string formatting
  74. " python_highlight_string_format Highlight str.format syntax
  75. " python_highlight_string_templates Highlight string.Template syntax
  76. " python_highlight_indent_errors Highlight indentation errors
  77. " python_highlight_space_errors Highlight trailing spaces
  78. " python_highlight_doctests Highlight doc-tests
  79. " python_print_as_function Highlight 'print' statement as
  80. " function for Python 2
  81. " python_highlight_file_headers_as_comments
  82. " Highlight shebang and coding
  83. " headers as comments
  84. "
  85. " python_highlight_all Enable all the options above
  86. " NOTE: This option don't override
  87. " any previously set options
  88. "
  89. " python_slow_sync Can be set to 0 for slow machines
  90. "
  91. " For version 5.x: Clear all syntax items
  92. " For versions greater than 6.x: Quit when a syntax file was already loaded
  93. if version < 600
  94. syntax clear
  95. elseif exists("b:current_syntax")
  96. finish
  97. endif
  98. "
  99. " Commands
  100. "
  101. command! -buffer Python2Syntax let b:python_version_2 = 1 | let &syntax=&syntax
  102. command! -buffer Python3Syntax let b:python_version_2 = 0 | let &syntax=&syntax
  103. " Enable option if it's not defined
  104. function! s:EnableByDefault(name)
  105. if !exists(a:name)
  106. let {a:name} = 1
  107. endif
  108. endfunction
  109. " Check if option is enabled
  110. function! s:Enabled(name)
  111. return exists(a:name) && {a:name}
  112. endfunction
  113. " Is it Python 2 syntax?
  114. function! s:Python2Syntax()
  115. if exists("b:python_version_2")
  116. return b:python_version_2
  117. endif
  118. return s:Enabled("g:python_version_2")
  119. endfunction
  120. "
  121. " Default options
  122. "
  123. call s:EnableByDefault("g:python_slow_sync")
  124. if s:Enabled("g:python_highlight_all")
  125. call s:EnableByDefault("g:python_highlight_builtins")
  126. if s:Enabled("g:python_highlight_builtins")
  127. call s:EnableByDefault("g:python_highlight_builtin_objs")
  128. call s:EnableByDefault("g:python_highlight_builtin_funcs")
  129. endif
  130. call s:EnableByDefault("g:python_highlight_exceptions")
  131. call s:EnableByDefault("g:python_highlight_string_formatting")
  132. call s:EnableByDefault("g:python_highlight_string_format")
  133. call s:EnableByDefault("g:python_highlight_string_templates")
  134. call s:EnableByDefault("g:python_highlight_indent_errors")
  135. call s:EnableByDefault("g:python_highlight_space_errors")
  136. call s:EnableByDefault("g:python_highlight_doctests")
  137. call s:EnableByDefault("g:python_print_as_function")
  138. endif
  139. "
  140. " Keywords
  141. "
  142. syn keyword pythonStatement break continue del
  143. syn keyword pythonStatement exec return
  144. syn keyword pythonStatement pass raise
  145. syn keyword pythonStatement global assert
  146. syn keyword pythonStatement lambda
  147. syn keyword pythonStatement with
  148. syn keyword pythonStatement def class nextgroup=pythonFunction skipwhite
  149. syn keyword pythonRepeat for while
  150. syn keyword pythonConditional if elif else
  151. " The standard pyrex.vim unconditionally removes the pythonInclude group, so
  152. " we provide a dummy group here to avoid crashing pyrex.vim.
  153. syn keyword pythonInclude import
  154. syn keyword pythonImport import
  155. syn match pythonIdentifier "\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*" nextgroup=pythonFuncArgs,pythonTypeAnno display
  156. syn keyword pythonException try except finally
  157. syn keyword pythonOperator and in is not or
  158. syn region pythonDictSetExpr matchgroup=pythonDictSetExpr start='{' end='}' contains=@pythonExpression
  159. syn region pythonFuncArgs matchgroup=pythonFuncArgs start='(' end=')' contained contains=pythonTypeAnno,@pythonExpression
  160. syn match pythonTypeAnno ":\s*\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*"hs=s+1 display contained contains=pythonType nextgroup=pythonTypeArgs
  161. syn match pythonTypeAnnoReturn "->\s*\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*"hs=s+2,he=e-1 display contains=pythonType nextgroup=pythonTypeArgs
  162. syn region pythonTypeArgs matchgroup=pythonTypeArgs start='\[' end='\]' display contained contains=pythonType,pythonTypeArgs
  163. syn keyword pythonType Any AnyStr Callable ClassVar Tuple Union Optional Type TypeVar None contained
  164. syn keyword pythonType AbstractSet MutableSet Mapping MutableMapping Sequence MutableSequence ByteString Deque List contained
  165. syn keyword pythonType Set FrozenSet MappingView KeysView ItemsView ValuesView Awaitable Coroutine AsyncIterable contained
  166. syn keyword pythonType AsyncIterator ContextManager Dict DefaultDict Generator AsyncGenerator Text NamedTuple contained
  167. syn keyword pythonType Iterable Iterator Reversible SupportsInt SupportsFloat SupportsAbs SupportsRound Container contained
  168. syn keyword pythonType Hashable Sized Collection contained
  169. syn match pythonStatement "\<yield\>" display
  170. syn match pythonImport "\<from\>" display
  171. if s:Python2Syntax()
  172. if !s:Enabled("g:python_print_as_function")
  173. syn keyword pythonStatement print
  174. endif
  175. syn keyword pythonImport as
  176. syn match pythonFunction "[a-zA-Z_][a-zA-Z0-9_]*" display contained
  177. else
  178. syn keyword pythonStatement as nonlocal
  179. syn match pythonStatement "\<yield\s\+from\>" display
  180. syn keyword pythonBuiltinObj None True False
  181. syn match pythonFunction "\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*" nextgroup=pythonFuncArgs display contained
  182. syn keyword pythonStatement await async
  183. syn match pythonStatement "\<async\s\+def\>" display nextgroup=pythonFunction skipwhite
  184. syn match pythonStatement "\<async\s\+with\>" display
  185. syn match pythonStatement "\<async\s\+for\>" display
  186. endif
  187. syn cluster pythonExpression contains=
  188. \ pythonFuncArgs,
  189. \ pythonDictSetExpr,
  190. \ pythonStatement,
  191. \ pythonRepeat,
  192. \ pythonConditional,
  193. \ pythonComment,
  194. \ pythonOperator,
  195. \ pythonNumber,
  196. \ pythonNumberError,
  197. \ pythonFloat,
  198. \ pythonHexNumber,
  199. \ pythonOctNumber,
  200. \ pythonBytes,
  201. \ pythonString,
  202. \ pythonRawString,
  203. \ pythonUniString,
  204. \ pythonUniRawString,
  205. \ pythonFString,
  206. \ pythonExClass,
  207. \ pythonBuiltinObj,
  208. \ pythonBuiltinFunc
  209. syn cluster pythonFExpression contains=
  210. \ pythonStatement,
  211. \ pythonRepeat,
  212. \ pythonConditional,
  213. \ pythonOperator,
  214. \ pythonNumber,
  215. \ pythonHexNumber,
  216. \ pythonOctNumber,
  217. \ pythonBinNumber,
  218. \ pythonFloat,
  219. \ pythonString,
  220. \ pythonBytes,
  221. \ pythonBuiltinObj,
  222. \ pythonBuiltinFunc
  223. "
  224. " Decorators (new in Python 2.4)
  225. "
  226. syn match pythonDecorator "^\s*\zs@" display nextgroup=pythonDottedName skipwhite
  227. if s:Python2Syntax()
  228. syn match pythonDottedName "[a-zA-Z_][a-zA-Z0-9_]*\%(\.[a-zA-Z_][a-zA-Z0-9_]*\)*" display contained
  229. else
  230. syn match pythonDottedName "\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\%(\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\)*" display contained
  231. endif
  232. syn match pythonDot "\." display containedin=pythonDottedName
  233. "
  234. " Comments
  235. "
  236. syn match pythonComment "#.*$" display contains=pythonTodo,@Spell
  237. if !s:Enabled("g:python_highlight_file_headers_as_comments")
  238. syn match pythonRun "\%^#!.*$"
  239. syn match pythonCoding "\%^.*\%(\n.*\)\?#.*coding[:=]\s*[0-9A-Za-z-_.]\+.*$"
  240. endif
  241. syn keyword pythonTodo TODO FIXME XXX contained
  242. "
  243. " Errors
  244. "
  245. syn match pythonError "\<\d\+\D\+\>" display
  246. syn match pythonError "[$?]" display
  247. syn match pythonError "[&|]\{2,}" display
  248. syn match pythonError "[=]\{3,}" display
  249. " Mixing spaces and tabs also may be used for pretty formatting multiline
  250. " statements
  251. if s:Enabled("g:python_highlight_indent_errors")
  252. syn match pythonIndentError "^\s*\%( \t\|\t \)\s*\S"me=e-1 display
  253. endif
  254. " Trailing space errors
  255. if s:Enabled("g:python_highlight_space_errors")
  256. syn match pythonSpaceError "\s\+$" display
  257. endif
  258. "
  259. " Strings
  260. "
  261. if s:Python2Syntax()
  262. " Python 2 strings
  263. syn region pythonString start=+[bB]\='+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  264. syn region pythonString start=+[bB]\="+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  265. syn region pythonString start=+[bB]\="""+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
  266. syn region pythonString start=+[bB]\='''+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
  267. else
  268. " Python 3 byte strings
  269. syn region pythonBytes start=+[bB]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesError,pythonBytesContent,@Spell
  270. syn region pythonBytes start=+[bB]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesError,pythonBytesContent,@Spell
  271. syn region pythonBytes start=+[bB]"""+ end=+"""+ keepend contains=pythonBytesError,pythonBytesContent,pythonDocTest2,pythonSpaceError,@Spell
  272. syn region pythonBytes start=+[bB]'''+ end=+'''+ keepend contains=pythonBytesError,pythonBytesContent,pythonDocTest,pythonSpaceError,@Spell
  273. syn match pythonBytesError ".\+" display contained
  274. syn match pythonBytesContent "[\u0000-\u00ff]\+" display contained contains=pythonBytesEscape,pythonBytesEscapeError
  275. endif
  276. syn match pythonBytesEscape +\\[abfnrtv'"\\]+ display contained
  277. syn match pythonBytesEscape "\\\o\o\=\o\=" display contained
  278. syn match pythonBytesEscapeError "\\\o\{,2}[89]" display contained
  279. syn match pythonBytesEscape "\\x\x\{2}" display contained
  280. syn match pythonBytesEscapeError "\\x\x\=\X" display contained
  281. syn match pythonBytesEscape "\\$"
  282. syn match pythonUniEscape "\\u\x\{4}" display contained
  283. syn match pythonUniEscapeError "\\u\x\{,3}\X" display contained
  284. syn match pythonUniEscape "\\U\x\{8}" display contained
  285. syn match pythonUniEscapeError "\\U\x\{,7}\X" display contained
  286. syn match pythonUniEscape "\\N{[A-Z ]\+}" display contained
  287. syn match pythonUniEscapeError "\\N{[^A-Z ]\+}" display contained
  288. if s:Python2Syntax()
  289. " Python 2 Unicode strings
  290. syn region pythonUniString start=+[uU]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  291. syn region pythonUniString start=+[uU]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  292. syn region pythonUniString start=+[uU]"""+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
  293. syn region pythonUniString start=+[uU]'''+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
  294. else
  295. " Python 3 strings
  296. syn region pythonString start=+'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  297. syn region pythonString start=+"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  298. syn region pythonString start=+"""+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
  299. syn region pythonString start=+'''+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
  300. syn region pythonFString start=+[fF]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  301. syn region pythonFString start=+[fF]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,@Spell
  302. syn region pythonFString start=+[fF]"""+ end=+"""+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest2,pythonSpaceError,@Spell
  303. syn region pythonFString start=+[fF]'''+ end=+'''+ keepend contains=pythonBytesEscape,pythonBytesEscapeError,pythonUniEscape,pythonUniEscapeError,pythonDocTest,pythonSpaceError,@Spell
  304. endif
  305. if s:Python2Syntax()
  306. " Python 2 Unicode raw strings
  307. syn region pythonUniRawString start=+[uU][rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,pythonUniRawEscape,pythonUniRawEscapeError,@Spell
  308. syn region pythonUniRawString start=+[uU][rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,pythonUniRawEscape,pythonUniRawEscapeError,@Spell
  309. syn region pythonUniRawString start=+[uU][rR]"""+ end=+"""+ keepend contains=pythonUniRawEscape,pythonUniRawEscapeError,pythonDocTest2,pythonSpaceError,@Spell
  310. syn region pythonUniRawString start=+[uU][rR]'''+ end=+'''+ keepend contains=pythonUniRawEscape,pythonUniRawEscapeError,pythonDocTest,pythonSpaceError,@Spell
  311. syn match pythonUniRawEscape "\([^\\]\(\\\\\)*\)\@<=\\u\x\{4}" display contained
  312. syn match pythonUniRawEscapeError "\([^\\]\(\\\\\)*\)\@<=\\u\x\{,3}\X" display contained
  313. endif
  314. " Python 2/3 raw strings
  315. if s:Python2Syntax()
  316. syn region pythonRawString start=+[bB]\=[rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
  317. syn region pythonRawString start=+[bB]\=[rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
  318. syn region pythonRawString start=+[bB]\=[rR]"""+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
  319. syn region pythonRawString start=+[bB]\=[rR]'''+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
  320. else
  321. syn region pythonRawString start=+[rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
  322. syn region pythonRawString start=+[rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
  323. syn region pythonRawString start=+[rR]"""+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
  324. syn region pythonRawString start=+[rR]'''+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
  325. syn region pythonRawBytes start=+[bB][rR]'+ skip=+\\\\\|\\'\|\\$+ excludenl end=+'+ end=+$+ keepend contains=pythonRawEscape,@Spell
  326. syn region pythonRawBytes start=+[bB][rR]"+ skip=+\\\\\|\\"\|\\$+ excludenl end=+"+ end=+$+ keepend contains=pythonRawEscape,@Spell
  327. syn region pythonRawBytes start=+[bB][rR]"""+ end=+"""+ keepend contains=pythonDocTest2,pythonSpaceError,@Spell
  328. syn region pythonRawBytes start=+[bB][rR]'''+ end=+'''+ keepend contains=pythonDocTest,pythonSpaceError,@Spell
  329. endif
  330. syn match pythonRawEscape +\\['"]+ display transparent contained
  331. if s:Enabled("g:python_highlight_string_formatting")
  332. " % operator string formatting
  333. if s:Python2Syntax()
  334. syn match pythonStrFormatting "%\%(([^)]\+)\)\=[-#0 +]*\d*\%(\.\d\+\)\=[hlL]\=[diouxXeEfFgGcrs%]" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  335. syn match pythonStrFormatting "%[-#0 +]*\%(\*\|\d\+\)\=\%(\.\%(\*\|\d\+\)\)\=[hlL]\=[diouxXeEfFgGcrs%]" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  336. else
  337. syn match pythonStrFormatting "%\%(([^)]\+)\)\=[-#0 +]*\d*\%(\.\d\+\)\=[hlL]\=[diouxXeEfFgGcrs%]" contained containedin=pythonString,pythonRawString
  338. syn match pythonStrFormatting "%[-#0 +]*\%(\*\|\d\+\)\=\%(\.\%(\*\|\d\+\)\)\=[hlL]\=[diouxXeEfFgGcrs%]" contained containedin=pythonString,pythonRawString
  339. endif
  340. endif
  341. if s:Enabled("g:python_highlight_string_format")
  342. " str.format syntax
  343. if s:Python2Syntax()
  344. syn match pythonStrFormat "{{\|}}" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  345. syn match pythonStrFormat "{\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)\=\%(\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\[\%(\d\+\|[^!:\}]\+\)\]\)*\%(![rsa]\)\=\%(:\%({\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)}\|\%([^}]\=[<>=^]\)\=[ +-]\=#\=0\=\d*,\=\%(\.\d\+\)\=[bcdeEfFgGnosxX%]\=\)\=\)\=}" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  346. else
  347. syn match pythonStrFormat "{{\|}}" contained containedin=pythonString,pythonRawString,pythonFString
  348. syn match pythonStrFormat "{\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)\=\%(\.\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\[\%(\d\+\|[^!:\}]\+\)\]\)*\%(![rsa]\)\=\%(:\%({\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)}\|\%([^}]\=[<>=^]\)\=[ +-]\=#\=0\=\d*,\=\%(\.\d\+\)\=[bcdeEfFgGnosxX%]\=\)\=\)\=}" contained containedin=pythonString,pythonRawString
  349. syn region pythonStrInterpRegion start="{"he=e+1,rs=e+1 end="\%(![rsa]\)\=\%(:\%({\%(\%([^[:cntrl:][:space:][:punct:][:digit:]]\|_\)\%([^[:cntrl:][:punct:][:space:]]\|_\)*\|\d\+\)}\|\%([^}]\=[<>=^]\)\=[ +-]\=#\=0\=\d*,\=\%(\.\d\+\)\=[bcdeEfFgGnosxX%]\=\)\=\)\=}"hs=s-1,re=s-1 extend contained containedin=pythonFString contains=pythonStrInterpRegion,@pythonFExpression
  350. endif
  351. endif
  352. if s:Enabled("g:python_highlight_string_templates")
  353. " string.Template format
  354. if s:Python2Syntax()
  355. syn match pythonStrTemplate "\$\$" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  356. syn match pythonStrTemplate "\${[a-zA-Z_][a-zA-Z0-9_]*}" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  357. syn match pythonStrTemplate "\$[a-zA-Z_][a-zA-Z0-9_]*" contained containedin=pythonString,pythonUniString,pythonUniRawString,pythonRawString
  358. else
  359. syn match pythonStrTemplate "\$\$" contained containedin=pythonString,pythonRawString
  360. syn match pythonStrTemplate "\${[a-zA-Z_][a-zA-Z0-9_]*}" contained containedin=pythonString,pythonRawString
  361. syn match pythonStrTemplate "\$[a-zA-Z_][a-zA-Z0-9_]*" contained containedin=pythonString,pythonRawString
  362. endif
  363. endif
  364. if s:Enabled("g:python_highlight_doctests")
  365. " DocTests
  366. syn region pythonDocTest start="^\s*>>>" end=+'''+he=s-1 end="^\s*$" contained
  367. syn region pythonDocTest2 start="^\s*>>>" end=+"""+he=s-1 end="^\s*$" contained
  368. endif
  369. "
  370. " Numbers (ints, longs, floats, complex)
  371. "
  372. if s:Python2Syntax()
  373. syn match pythonHexError "\<0[xX]\x*[g-zG-Z]\+\x*[lL]\=\>" display
  374. syn match pythonOctError "\<0[oO]\=\o*\D\+\d*[lL]\=\>" display
  375. syn match pythonBinError "\<0[bB][01]*\D\+\d*[lL]\=\>" display
  376. syn match pythonHexNumber "\<0[xX]\x\+[lL]\=\>" display
  377. syn match pythonOctNumber "\<0[oO]\o\+[lL]\=\>" display
  378. syn match pythonBinNumber "\<0[bB][01]\+[lL]\=\>" display
  379. syn match pythonNumberError "\<\d\+\D[lL]\=\>" display
  380. syn match pythonNumber "\<\d[lL]\=\>" display
  381. syn match pythonNumber "\<[0-9]\d\+[lL]\=\>" display
  382. syn match pythonNumber "\<\d\+[lLjJ]\>" display
  383. syn match pythonOctError "\<0[oO]\=\o*[8-9]\d*[lL]\=\>" display
  384. syn match pythonBinError "\<0[bB][01]*[2-9]\d*[lL]\=\>" display
  385. syn match pythonFloat "\.\d\+\%([eE][+-]\=\d\+\)\=[jJ]\=\>" display
  386. syn match pythonFloat "\<\d\+[eE][+-]\=\d\+[jJ]\=\>" display
  387. syn match pythonFloat "\<\d\+\.\d*\%([eE][+-]\=\d\+\)\=[jJ]\=" display
  388. else
  389. syn match pythonHexError "\<0[xX]\x*[g-zG-Z]\x*\>" display
  390. syn match pythonOctError "\<0[oO]\=\o*\D\+\d*\>" display
  391. syn match pythonBinError "\<0[bB][01]*\D\+\d*\>" display
  392. syn match pythonHexNumber "\<0[xX][_0-9a-fA-F]*\x\>" display
  393. syn match pythonOctNumber "\<0[oO][_0-7]*\o\>" display
  394. syn match pythonBinNumber "\<0[bB][_01]*[01]\>" display
  395. syn match pythonNumberError "\<\d[_0-9]*\D\>" display
  396. syn match pythonNumberError "\<0[_0-9]\+\>" display
  397. syn match pythonNumberError "\<\d[_0-9]*_\>" display
  398. syn match pythonNumber "\<\d\>" display
  399. syn match pythonNumber "\<[1-9][_0-9]*\d\>" display
  400. syn match pythonNumber "\<\d[jJ]\>" display
  401. syn match pythonNumber "\<[1-9][_0-9]*\d[jJ]\>" display
  402. syn match pythonOctError "\<0[oO]\=\o*[8-9]\d*\>" display
  403. syn match pythonBinError "\<0[bB][01]*[2-9]\d*\>" display
  404. syn match pythonFloat "\.\d\%([_0-9]*\d\)\=\%([eE][+-]\=\d\%([_0-9]*\d\)\=\)\=[jJ]\=\>" display
  405. syn match pythonFloat "\<\d\%([_0-9]*\d\)\=[eE][+-]\=\d\%([_0-9]*\d\)\=[jJ]\=\>" display
  406. syn match pythonFloat "\<\d\%([_0-9]*\d\)\=\.\d\%([_0-9]*\d\)\=\%([eE][+-]\=\d\%([_0-9]*\d\)\=\)\=[jJ]\=" display
  407. endif
  408. "
  409. " Builtin objects and types
  410. "
  411. if s:Enabled("g:python_highlight_builtin_objs")
  412. if s:Python2Syntax()
  413. syn keyword pythonBuiltinObj None False True
  414. endif
  415. syn keyword pythonBuiltinObj Ellipsis NotImplemented self cls
  416. syn keyword pythonBuiltinObj __debug__ __doc__ __file__ __name__ __package__
  417. endif
  418. "
  419. " Builtin functions
  420. "
  421. if s:Enabled("g:python_highlight_builtin_funcs")
  422. if s:Python2Syntax()
  423. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(apply|basestring|buffer|callable|coerce)>\ze\(' nextgroup=pythonFuncArgs
  424. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(execfile|file|help|intern|long|raw_input)>\ze\(' nextgroup=pythonFuncArgs
  425. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(reduce|reload|unichr|unicode|xrange)>\ze\(' nextgroup=pythonFuncArgs
  426. if s:Enabled("g:python_print_as_function")
  427. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(print)>\ze\(' nextgroup=pythonFuncArgs
  428. endif
  429. else
  430. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(ascii|exec|memoryview|print)\ze\(>' nextgroup=pythonFuncArgs
  431. endif
  432. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(__import__|abs|all|any)>\ze\(' nextgroup=pythonFuncArgs
  433. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(bin|bool|bytearray|bytes)>\ze\(' nextgroup=pythonFuncArgs
  434. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(chr|classmethod|cmp|compile|complex)>\ze\(' nextgroup=pythonFuncArgs
  435. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(delattr|dict|dir|divmod|enumerate|eval)>\ze\(' nextgroup=pythonFuncArgs
  436. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(filter|float|format|frozenset|getattr)>\ze\(' nextgroup=pythonFuncArgs
  437. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(globals|hasattr|hash|hex|id)>\ze\(' nextgroup=pythonFuncArgs
  438. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(input|int|isinstance)>\ze\(' nextgroup=pythonFuncArgs
  439. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(issubclass|iter|len|list|locals|map|max)>\ze\(' nextgroup=pythonFuncArgs
  440. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(min|next|object|oct|open|ord)>\ze\(' nextgroup=pythonFuncArgs
  441. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(pow|property|range)>\ze\(' nextgroup=pythonFuncArgs
  442. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(repr|reversed|round|set|setattr)>\ze\(' nextgroup=pythonFuncArgs
  443. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(slice|sorted|staticmethod|str|sum|super|tuple)>\ze\(' nextgroup=pythonFuncArgs
  444. syn match pythonBuiltinFunc '\v(\.)@<!\zs<(type|vars|zip)>\ze\(' nextgroup=pythonFuncArgs
  445. endif
  446. "
  447. " Builtin exceptions and warnings
  448. "
  449. if s:Enabled("g:python_highlight_exceptions")
  450. if s:Python2Syntax()
  451. syn keyword pythonExClass StandardError nextgroup=pythonFuncArgs
  452. else
  453. syn keyword pythonExClass BlockingIOError ChildProcessError nextgroup=pythonFuncArgs
  454. syn keyword pythonExClass ConnectionError BrokenPipeError nextgroup=pythonFuncArgs
  455. syn keyword pythonExClass ConnectionAbortedError ConnectionRefusedError nextgroup=pythonFuncArgs
  456. syn keyword pythonExClass ConnectionResetError FileExistsError nextgroup=pythonFuncArgs
  457. syn keyword pythonExClass FileNotFoundError InterruptedError nextgroup=pythonFuncArgs
  458. syn keyword pythonExClass IsADirectoryError NotADirectoryError nextgroup=pythonFuncArgs
  459. syn keyword pythonExClass PermissionError ProcessLookupError TimeoutError nextgroup=pythonFuncArgs
  460. syn keyword pythonExClass ResourceWarning nextgroup=pythonFuncArgs
  461. endif
  462. syn keyword pythonExClass BaseException nextgroup=pythonFuncArgs
  463. syn keyword pythonExClass Exception ArithmeticError nextgroup=pythonFuncArgs
  464. syn keyword pythonExClass LookupError EnvironmentError nextgroup=pythonFuncArgs
  465. syn keyword pythonExClass AssertionError AttributeError BufferError EOFError nextgroup=pythonFuncArgs
  466. syn keyword pythonExClass FloatingPointError GeneratorExit IOError nextgroup=pythonFuncArgs
  467. syn keyword pythonExClass ImportError IndexError KeyError nextgroup=pythonFuncArgs
  468. syn keyword pythonExClass KeyboardInterrupt MemoryError NameError nextgroup=pythonFuncArgs
  469. syn keyword pythonExClass NotImplementedError OSError OverflowError nextgroup=pythonFuncArgs
  470. syn keyword pythonExClass ReferenceError RuntimeError StopIteration nextgroup=pythonFuncArgs
  471. syn keyword pythonExClass SyntaxError IndentationError TabError nextgroup=pythonFuncArgs
  472. syn keyword pythonExClass SystemError SystemExit TypeError nextgroup=pythonFuncArgs
  473. syn keyword pythonExClass UnboundLocalError UnicodeError nextgroup=pythonFuncArgs
  474. syn keyword pythonExClass UnicodeEncodeError UnicodeDecodeError nextgroup=pythonFuncArgs
  475. syn keyword pythonExClass UnicodeTranslateError ValueError VMSError nextgroup=pythonFuncArgs
  476. syn keyword pythonExClass WindowsError ZeroDivisionError nextgroup=pythonFuncArgs
  477. syn keyword pythonExClass Warning UserWarning BytesWarning DeprecationWarning nextgroup=pythonFuncArgs
  478. syn keyword pythonExClass PendingDepricationWarning SyntaxWarning nextgroup=pythonFuncArgs
  479. syn keyword pythonExClass RuntimeWarning FutureWarning nextgroup=pythonFuncArgs
  480. syn keyword pythonExClass ImportWarning UnicodeWarning nextgroup=pythonFuncArgs
  481. endif
  482. if s:Enabled("g:python_slow_sync")
  483. syn sync minlines=2000
  484. else
  485. " This is fast but code inside triple quoted strings screws it up. It
  486. " is impossible to fix because the only way to know if you are inside a
  487. " triple quoted string is to start from the beginning of the file.
  488. syn sync match pythonSync grouphere NONE "):$"
  489. syn sync maxlines=200
  490. endif
  491. if version >= 508 || !exists("did_python_syn_inits")
  492. if version <= 508
  493. let did_python_syn_inits = 1
  494. command -nargs=+ HiLink hi link <args>
  495. else
  496. command -nargs=+ HiLink hi def link <args>
  497. endif
  498. HiLink pythonStatement Statement
  499. HiLink pythonImport Include
  500. HiLink pythonFunction Function
  501. HiLink pythonConditional Conditional
  502. HiLink pythonRepeat Repeat
  503. HiLink pythonException Exception
  504. HiLink pythonOperator Operator
  505. HiLink pythonDecorator Define
  506. HiLink pythonDottedName Function
  507. HiLink pythonDot Normal
  508. HiLink pythonComment Comment
  509. if !s:Enabled("g:python_highlight_file_headers_as_comments")
  510. HiLink pythonCoding Special
  511. HiLink pythonRun Special
  512. endif
  513. HiLink pythonTodo Todo
  514. HiLink pythonError Error
  515. HiLink pythonIndentError Error
  516. HiLink pythonSpaceError Error
  517. HiLink pythonString String
  518. HiLink pythonRawString String
  519. HiLink pythonUniEscape Special
  520. HiLink pythonUniEscapeError Error
  521. if s:Python2Syntax()
  522. HiLink pythonUniString String
  523. HiLink pythonUniRawString String
  524. HiLink pythonUniRawEscape Special
  525. HiLink pythonUniRawEscapeError Error
  526. else
  527. HiLink pythonBytes String
  528. HiLink pythonRawBytes String
  529. HiLink pythonBytesContent String
  530. HiLink pythonBytesError Error
  531. HiLink pythonBytesEscape Special
  532. HiLink pythonBytesEscapeError Error
  533. HiLink pythonFString String
  534. HiLink pythonStrInterpRegion Special
  535. endif
  536. HiLink pythonStrFormatting Special
  537. HiLink pythonStrFormat Special
  538. HiLink pythonStrTemplate Special
  539. HiLink pythonDocTest Special
  540. HiLink pythonDocTest2 Special
  541. HiLink pythonNumber Number
  542. HiLink pythonHexNumber Number
  543. HiLink pythonOctNumber Number
  544. HiLink pythonBinNumber Number
  545. HiLink pythonFloat Float
  546. HiLink pythonNumberError Error
  547. HiLink pythonOctError Error
  548. HiLink pythonHexError Error
  549. HiLink pythonBinError Error
  550. HiLink pythonBuiltinObj Structure
  551. HiLink pythonBuiltinFunc Function
  552. HiLink pythonExClass Structure
  553. HiLink pythonTypeAnno Optional
  554. HiLink pythonTypeAnnoReturn Optional
  555. HiLink pythonTypeArgs Optional
  556. HiLink pythonType Special
  557. delcommand HiLink
  558. " default style for custom highlight group (may be overriden in colors)
  559. hi Optional gui=italic cterm=italic
  560. endif
  561. let b:current_syntax = "python"